Key features:
multiple data sets, Greek letters, subscripts, different types of error bars, custom ordinate magnitude label, legend with border, difference function, publication quality, vector file output (.eps)
Embedded Files
This image is Fig. 1 from my second publication.
reset
set terminal postscript eps color enhanced "Helvetica" 25 size 4.676,3.5 ## good ratio for publication: 1.336
set output "fig1-v8.eps" ## output filename
set title ""
set xlabel "Temperature (K)" offset 0,.5
set ylabel "({/Symbol \147} - {/Symbol \147}_{IAPWS})/{/Symbol \147}_{ref}" offset 1.5,0
set tics scale 2.5
set xtic 203,5,350 offset 0,.1 nomirror ## this is the spacing between tics on the x-axis
set mxtics 2 ## this sets the frequency of the MINOR x-tics;
set ytic -10,1,10 offset .5,0 nomirror ## this is the spacing between tics on the y-axis
#set mytics 2 ## this sets the v of the MINOR y-tics
set xrange [246.5:274]
set yrange [-2:4.5]
set label "x 10^{-3}" at graph -.02,1.035 font "Helvetica,20"
unset grid ## alternatively, use "with lines" after "plot"
set samples 10000 ## default=100... improves smoothness
set border 15 lw 2
set key samplen 0.5 ###invert
set key spacing 2
###set key vertical
set key maxrows 4 ## selects multi-column legend
###set key maxcols 2 ## selects multi-column legend
###set key height -1 ## number of character spaces to lengthen/shorten legend by
###set key width +.5 ## number of character spaces to lengthen/shorten legend by
set key box lw 1.5 at 274, 4.5 ## legend; option: "nobox"
set pointsize 2
set bars small ## removes "caps" from errorbars
iapws(x) = B*((1-(x/Tc))**mu)*(1+b*(1-(x/Tc)))
B = 235.8
b = -.625
mu = 1.256
Tc = 647.096
sigref2015 = 71.19
sigref2014 = 72.74
zero(x) = 0
#----- Notice that I have rigged "small" x-error bars to be the horizontal lines.
#----- Also, the very last "plot" command is meaningless-- just in order to get a blank "title" space.
#----- The same plots appear twice in some cases for layering effects + legend ordering.
###set label "{/Symbol \163}_{ind} {/Symbol \364}" at graph .835,0.73
set label "{/Symbol \163}_{ind} {/Symbol \364}" at graph .835,0.81
plot zero(x) lc rgb "white" lw 2 notitle, \
zero(x) lc rgb "black" lw 2 notitle, \
"hruby_6errors.dat" u 1:(1000*((($2-iapws($1))/sigref2015)+$7)):($8*.7) with xerrorbars pt 0 lc rgb "black" lw 4 notitle, \
"hruby_6errors.dat" u 1:(1000*((($2-iapws($1))/sigref2015)-$7)):($8*.7) with xerrorbars pt 0 lc rgb "black" lw 4 notitle, \
"hruby_6errors.dat" u 1:(1000*(($2-iapws($1))/sigref2015)):(1000*($5/sigref2015)) with yerrorbars pt 0 lc rgb "black" lw 4 notitle, \
"hruby_jpcl5_prague.dat" u 1:(1000*(($2-iapws($1))/sigref2014)) pt 9 lt 4 ps 3 lw 3 title "h 2014", \
"hruby_jpcb199_p1.dat" u 1:(1000*(($2-iapws($1))/sigref2015)) pt 1 lt 1 ps 2.5 lw 3 title "p-1 2015", \
"hruby_jpcb199_p2.dat" u 1:(1000*(($2-iapws($1))/sigref2015)) pt 2 lt 2 lw 3 title "p-2 2015", \
"hruby_jpcb199_h1.dat" u 1:(1000*(($2-iapws($1))/sigref2015)) pt 64 lt 3 lw 3 title "h-1 2015", \
"hruby_jpcb199_h2.dat" u 1:(1000*(($2-iapws($1))/sigref2015)) pt 65 lt 7 lw 3 title "h-2 2015", \
"hruby_6errors.dat" u 1:(1000*((($2-iapws($1))/sigref2015)-$7)):($8*.7) with xerrorbars pt 0 lc rgb "black" lw 4 title "{/Symbol \163}_{Hru}", \
"hruby_6errors.dat" u 1:(1000*(($2-iapws($1))/sigref2015)):(1000*($5/sigref2015)) with yerrorbars pt 0 lc rgb "black" lw 4 notitle, \
"hruby_jpcl5_prague.dat" u 1:(1000*(($2-iapws($1))/sigref2014)) pt 9 lt 4 ps 3 lw 3 notitle, \
"hruby_jpcb199_p1.dat" u 1:(1000*(($2-iapws($1))/sigref2015)) pt 1 lt 1 ps 2.5 lw 3 notitle, \
"hruby_jpcb199_p2.dat" u 1:(1000*(($2-iapws($1))/sigref2015)) pt 2 lt 2 lw 3 notitle, \
"hruby_jpcb199_h1.dat" u 1:(1000*(($2-iapws($1))/sigref2015)) pt 64 lt 3 lw 3 notitle, \
"hruby_jpcb199_h2.dat" u 1:(1000*(($2-iapws($1))/sigref2015)) pt 65 lt 7 lw 3 notitle, \
"hruby_jpcb199_h1.dat" u 1:2 pt 0 lt 0 lw 0 title " "
##### EPS POINT TYPES #####
# 5 = filled box
# 7 = filled circle (dot)
# 8 = filled up triangle
# 11 = filled down triangle (small)
#
# 63 = filled diamond
# 64 = empty box
# 65 = empty circle
# 68 = empty diamond
# pointtype ("pt")
# 0 = none
# 1 = +
# 2 = X
# 3 = X & horz.line
# 4 = open box
# 5 = closed box
# 6 = open circle
# 7 = closed circ.
# 8 = open up triang.
# 9 = closed up triang.
# linetype ("lt")
# -1 = black
# 0 = grey dotted
# 1 = purple
# 2 = green
# 3 = sky blue
# 4 = orange
# 5 = yellow
# 6 = navy blue
# 7 = red
Page updated
Google Sites
Report abuse