Key features:
Text/labels within graph, remove/delete tick marks, get plot data from file, get data from different folder/directory, plot data from several files, mathematical manipulation of input data, scale input data, shift input data, superscripts, publication quality
This image is Fig. 9 from my fifth publication.
###On Pinnacle: module load gnuplot/5.2.0
reset # good idea to make sure you start "fresh"
set terminal pngcairo truecolor nocrop enhanced font "arial,80" size 6000,3000 # good ratio for publication: 1.336
set output "power_solutes_WithExperimental_v4.png" ## output filename
set multiplot layout 1,1 title ""
unset grid ## alternatively, use "with lines" after "plot"
set samples 10000 ## default=100... improves smoothness
set border 15 lw 9
set tics scale 1.5
#set label "{/Symbol s} = 0.3 (\305)" at graph .75,.4 font "arial bold,80"
set xlabel "Frequency (cm^{-1})" offset 0,0
set xrange [0:4200] ## options: "[min:max]" , "[:]" is "perfect" range,
#set format x "%1.1f" ## "%N.Mf" has N total digits, with M after the decimal.
#set xtics 0,0,0 offset 0,.25 out nomirror ## this is the spacing between tics on the x-axis
set mxtics 5 ## frequency of the MINOR x-tics;
set ylabel "Intensity (shifted, scaled)" #offset 1,0
set yrange [0:8000]
#set format y "%1.1f" ## "%N.Mf" has N total digits, with M after the decimal.
unset ytic
#set ytic 0,1000,10000 offset .75,-.1 nomirror ## spacing between tics on the y-axis
unset key
plot \
"2018-Wu-475-Fig1c_ethanol_SC_focused_greyscale_20C.txt" u 1:(6200+1500*$2) w lines lw 10 lc rgb "black" title "EtOH (Wu, et. al., 2018)",\
"2013-Qin-596-Fig4b.txt" u 1:(4200+.1*$2) w lines lw 10 lc rgb "black" title "Et (Qin, et. al., 2013)",\
"2018-Wu-475-Fig3a_methanol_SC_focused_greyscale_20C.txt" u 1:(2200+1500*$2) w lines lw 10 lc rgb "black" title "MeOH (Wu, et. al., 2018)",\
"2018-Wu-477-Fig1b_methane_SC_focused_greyscale_20C.txt" u 1:(300.+1500*$2) w lines lw 10 lc rgb "black" title "Me (Wu, et. al., 2018)"
# "2018-Wu-475-Fig1a_ethanol_raw_full_greyscale.txt" u 1:(6400+2500*$2) w lines lw 4 lc rgb "black" title "EtOH sol'n (Wu, et. al., 2018)",\
#set key spacing 1.5 ## vertical spacing between legend lines.
#set key samplen .5 ## length of line sample shown in legend.
##set key maxrows 7
##set key nobox at 13,1.8 ## where to put legend: x, y
#set key nobox bottom left ## where to put legend: left right center top bottom center
#set label "pure water" at 300,10100
set label "ethanol (aq)" at 300,6500
set label "ethane (aq)" at 300,4500
set label "methanol (aq)" at 300,2500
set label "methane (aq)" at 300,600
set xrange [0:4200] ## options: "[min:max]" , "[:]" is "perfect" range,
#These values use the scaling factor found in Table 6 of, "2007-Merrick-An evaluation of harmonic vibrati.pdf".
# "< tail -n +3000 power_water_pure_t100ps_dt.1fs.xvg" every 1 u ($1*.9598):(8000+$2) w lines lw 4 title "pure water",\#
plot \
"< tail -n +3000 power_ethanol_solute_t5x100ps_dt.1fs.txt" every 1 u ($1*.9598):(6000+0.04382*($2+$4+$6+$8+$10)/5) w lines lw 10 title "ethanol in water",\
"< tail -n +3000 power_ethane_solute_t5x100ps_dt.1fs.txt" every 1 u ($1*.9598):(4000+0.03522*($2+$4+$6+$8+$10)/5) w lines lw 10 title "ethane in water",\
"< tail -n +3000 power_methanol_solute_t5x100ps_dt.1fs.txt" every 1 u ($1*.9598):(2000+0.03554*($2+$4+$6+$8+$10)/5) w lines lw 10 title "methanol in water",\
"< tail -n +3000 power_methane_solute_t5x100ps_dt.1fs.txt" every 1 u ($1*.9598):(100.+0.04802*($2+$4+$6+$8+$10)/5) w lines lw 10 title "methane in water"
# "< head -3000 power_water_pure_t100ps_dt.1fs.xvg" every 1 u ($1*1.012):(8000+$2) w lines lw 4 title "pure water",\#
plot \
"< head -3000 power_ethanol_solute_t5x100ps_dt.1fs.txt" every 1 u ($1*1.012):(6000+0.04382*($2+$4+$6+$8+$10)/5) w lines lw 10 title "ethanol in water",\
"< head -3000 power_ethane_solute_t5x100ps_dt.1fs.txt" every 1 u ($1*1.012):(4000+0.03522*($2+$4+$6+$8+$10)/5) w lines lw 10 title "ethane in water",\
"< head -3000 power_methanol_solute_t5x100ps_dt.1fs.txt" every 1 u ($1*1.012):(2000+0.03554*($2+$4+$6+$8+$10)/5) w lines lw 10 title "methanol in water",\
"< head -3000 power_methane_solute_t5x100ps_dt.1fs.txt" every 1 u ($1*1.012):(100.+0.04802*($2+$4+$6+$8+$10)/5) w lines lw 10 title "methane in water"
unset multiplot
##################
# pointtype ("pt")
# 0 = none
# 1 = horz.line
# 2 = X
# 3 = X & horz.line
# 4 = open box
# 5 = closed box
# 6 = open circle
# 7 = closed circ.
# 8 = open up triang.
# 9 = closed up triang.
# 13= solid diamond
# 12= open diamond
# linetype ("lt")
# -1 = black
# 0 = grey dotted
# 1 = purple
# 2 = green
# 3 = sky blue
# 4 = orange
# 5 = yellow
# 6 = navy blue
# 7 = red
# \305 = Angstrom